@echo off

echo 開始解除kavo木馬病毒，請按下任意鍵...

pause >nul 2>nul

@set A=C D E F G H I J K L M N O P Q R S T U V W X Y Z

@set T=這個資料夾是用來防病毒的，所以故意取跟病毒的檔名一樣，這樣就能防止病毒寫入！「請勿刪除！」，近期發現部份軟體會將「AutoRun.inf」的資料夾給刪除掉，請隨時注意這個資料夾是否存在。 怪貓...

start /wait taskkill /f /im explorer.exe

cls

echo.

rem 刪除登錄檔中KAVO病毒的起動值

reg delete "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run" /v "kava" /f >nul 2>nul

reg delete "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run" /v "tava" /f >nul 2>nul

reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "tasa" /f >nul 2>nul

reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "mnsa" /f >nul 2>nul

echo.

rem 刪除個磁碟中的autorun.inf及ntdelect.com的病毒檔，並建立同名的資料夾，用以防止病毒寫入，屬性改成「唯讀、隱藏、系統」

for %%x in (%A%) do (

@if exist %%x:\autorun.inf attrib -r -s -h -a %%x:\autorun.inf >nul 2>nul

@del %%x:\autorun.inf /q /f >nul 2>nul

 

@if not exist %%x:\AUTORUN.INF md %%x:\AUTORUN.INF >nul 2>nul

@attrib +r +s +h %%x:\AUTORUN.INF >nul 2>nul

@echo %T%> %%x:\AUTORUN.INF\README.TXT

cls)

rem 病毒感染用的檔案刪除完成

echo.

rem 將被鎖定的隱藏檢視功能開啟(登錄檔)

reg.exe add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v "CheckedValue" /t REG_DWORD /d 00000001 /f >nul 2>nul

rem 已修復無法開啟檢視隱藏檔的功能，有需要請到資料夾中的資料夾選項去開啟檢視隱藏的功能，不需要就別開

cls

echo.

rem 刪除kavo的病毒主程式

attrib -s -h -r "%windir%\system32\kav*.*" >nul 2>nul&echo.&echo.& del "%windir%\system32\kav*.*" >nul 2>nul

attrib -s -h -r "%windir%\system32\tav*.*" >nul 2>nul&echo.&echo.& del "%windir%\system32\tav*.*" >nul 2>nul

echo.

@for %%z in (KAVO.EXE KAVO0.DLL KAVO1.DLL KAVO2.DLL TAVO.EXE TAVO0.DLL) do (if not exist "%windir%\system32\%%z" md "%windir%\system32\%%z" >nul 2>nul

attrib +s +h +r "%windir%\system32\%%z"

echo %T% > "%windir%\system32\%%z\README.TXT")

@cls

echo 刪除完成，kavo的病毒已成功解除，各磁碟的根目錄下會有autorun.inf的資料夾那是用來保護的！

echo.

echo 解毒完成，請將此畫面『關閉』後就可正常使用了，不過還是建議重開機會比較好。

echo 可以的話請將防毒軟體的病毒碼更新後再做一次全系統的病毒掃瞄，會更好只是會浪費很多時間。

call explorer.exe