.386

.model flat, stdcall

option casemap :none   ; case sensitive

include hd.h           ;//相关的头文件，你自己维护一个吧

.data

szCap   db "By Hume[AfO],2001...",0

szMsgOK db "It's now in the Per_Thread handler!",0

szMsg1 db "In normal,It would never Get here!",0

fmt     db "%s ",0dh,0ah,"  除法的商是:%d",0

buff    db 200 dup(0)

.code

_start:

  Assume FS:NOTHING

        push    offset perThread_Handler

        push    fs:[0]      

        mov     fs:[0],esp                       ;//建立SEH的基本ERR结构,如果不

;//明白,就仔细研究一下吧

        xor     ecx,ecx                          

        mov     eax,200

        cdq

        div    ecx

WouldBeOmit:                                   ;//正常情况以下永远不会被执行

        add     eax,100                         ;//这里不会执行,因为我们改变了eip的值   

        

ExecuteHere:

        div     ecx                             ;//从这里开始执行,从结果可以看到

        invoke    wsprintf,addr buff,addr fmt,addr szMsg1,eax        

        invoke    MessageBox,NULL,addr buff,addr szCap,40h+1000h

        pop     fs:[0]                          ;//修复后显示20,因为我们让ecx=10

        add     esp,4

        invoke    ExitProcess,NULL        

perThread_Handler proc \

uses ebx pExcept:DWORD,pFrame:DWORD,pContext:DWORD,pDispatch:DWORD        

        mov eax,pContext

  Assume eax:ptr CONTEXT

        mov     [eax].regEcx,20  ;//Ecx改变

        lea     ebx, ExecuteHere

        mov     [eax].regEip,ebx ;//从我们想要的地方开始执行,嘿嘿,这就是很多

;//反跟踪软件把你引向的黑暗之域

        mov     eax,0         ;//ExceptionContinueExecution,表示已经修复

;//CONTEXT,可从异常发生处

                              ;//reload并继续执行

    ret                    

perThread_Handler endp

end _start

[培训]《安卓高级研修班(网课)》月薪三万计划，掌握调试、分析还原ollvm、vmp的方法，定制art虚拟机自动化脱壳的方法